在Vim中交换两个字符串的最简单的方法?

最简单的方法是用string_b替换所有出现的string_a,同时将已经是string_b的任何内容更改为string_a?我当前的方法如下:

:s/string_a/string_c/g  
:s/string_b/string_a/g  
:s/string_c/string_b/g  

虽然这个工作,它需要额外的打字,似乎效率低下。有人知道更好的方法吗?

我会这样做:

:%s/\v(foo|bar)/\={'foo':'bar','bar':'foo'}[submatch(0)]/g

但是这太多打字,所以我会这样做:

function! Mirror(dict)
    for [key, value] in items(a:dict)
        let a:dict[value] = key
    endfor
    return a:dict
endfunction

function! S(number)
    return submatch(a:number)
endfunction

:%s/\v(foo|bar)/\=Mirror({'foo':'bar'})[S(0)]/g

但是,仍然需要键入foo和bar两次,所以我会做这样的事情:

function! SwapWords(dict, ...)
    let words = keys(a:dict) + values(a:dict)
    let words = map(words, 'escape(v:val, "|")')
    if(a:0 == 1)
        let delimiter = a:1
    else
        let delimiter = '/'
    endif
    let pattern = '\v(' . join(words, '|') . ')'
    exe '%s' . delimiter . pattern . delimiter
        \ . '\=' . string(Mirror(a:dict)) . '[S(0)]'
        \ . delimiter . 'g'
endfunction

:call SwapWords({'foo':'bar'})

如果你的一个单词包含一个/,你必须传入一个分隔符,你知道你的单词都不包含,例如

:call SwapWords({'foo/bar':'foo/baz'}, '@')

这也具有能够一次交换多对字的优点。

:call SwapWords({'foo':'bar', 'baz':'quux'})
http://stackoverflow.com/questions/3578549/easiest-way-to-swap-occurrences-of-two-strings-in-vim

本站文章除注明转载外,均为本站原创或编译
转载请明显位置注明出处:在Vim中交换两个字符串的最简单的方法?