entity-framework – f#:LINQ to Entities中仅支持无参数构造函数和初始值设定项

我试图从查询中获取Envelope.信封定义如下.

[<CLIMutable>]
type Envelope<'T> = {
    Id : Guid
    StreamId: Guid
    Created : DateTimeOffset
    Item : 'T }

MyLibAAS.DataStore.MyLibAASDbContext是用c#编写的EF DbContext.当我在f#中按如下方式扩展它时,我得到错误:LINQ to Entities中仅支持无参数构造函数和初始值设定项.

type MyLibAAS.DataStore.MyLibAASDbContext with 
    member this.GetEvents streamId = 
        query {
            for event in this.Events do
            where (event.StreamId = streamId)
            select {
                Id = event.Id;
                StreamId = streamId;
                Created = event.Timestamp;
                Item = (JsonConvert.DeserializeObject<QuestionnaireEvent> event.Payload)
            }
        } 

如果我返回事件并在事后将其映射到Envelope,它可以正常工作.

type MyLibAAS.DataStore.MyLibAASDbContext with 
    member this.GetEvents streamId = 
        query {
            for event in this.Events do
            where (event.StreamId = streamId)
            select event
        } |> Seq.map (fun event ->
                {
                    Id = event.Id
                    StreamId = streamId
                    Created = event.Timestamp
                    Item = (JsonConvert.DeserializeObject<QuestionnaireEvent> event.Payload)
                }
            )

为什么这会有所不同?信封类型甚至不是EF类型.

最佳答案
F#记录如何工作
F#记录被编译成具有只读属性的.NET类和一个构造函数,该构造函数将所有字段的值作为参数(加上一些接口).
例如,您的记录将以C#表示,大致如下:

public class Envelope<T> : IComparable<Envelope<T>>, IEquatable<Envelope<T>>, ...
{
   public Guid Id { get; private set; }
   public Guid StreamId { get; private set; }
   public DateTimeOffset Created { get; private set; }
   public T Item { get; private set; }

   public Envelope( Guid id, Guid streamId, DateTimeOffset created, T item ) {
      this.Id = id;
      this.StreamId = streamId;
      this.Created = created;
      this.Item = item;
   }

   // Plus implementations of IComparable, IEquatable, etc.
}

当您想要创建F#记录时,F#编译器会发出对此构造函数的调用,为所有字段提供值.
例如,查询的选择部分将在C#中查找,如下所示:

select new Envelope<QuestionnaireEvent>( 
   event.Id, streamId, event.Timestamp, 
   JsonConvert.DeserializeObject<QuestionnaireEvent>(event.Payload) )

实体框架限制
实际上,Entity Framework不允许在查询中调用非默认构造函数.有一个很好的理由:如果它允许它,原则上你可以构造一个这样的查询:

from e in ...
let env = new Envelope<E>( e.Id, ... )
where env.Id > 0
select env

实体框架不知道如何编译此查询,因为它不知道传递给构造函数的e.Id的值变为属性env.Id的值.对于F#记录,这总是如此,但对于其他.NET类则不然.
原则上,实体框架可以识别Envelope是一个F#记录,并应用构造函数参数和记录属性之间的连接知识.但事实并非如此.不幸的是,实体框架的设计者并没有将F#视为有效的用例.
(有趣的事实:C#匿名类型以相同的方式工作,EF确实为它们做了例外)

如何解决这个问题
为了使其工作,您需要将Envelope声明为具有默认构造函数的类型.唯一的方法是使它成为一个类,而不是一个记录:

type Envelope<'T>() =
   member val Id : Guid = Guid.Empty with get, set
   member val StreamId : Guid = Guid.Empty with get, set
   member val Created : DateTimeOffset = DateTimeOffset.MinValue with get, set
   member val Item : 'T = Unchecked.defaultof<'T> with get, set

然后使用属性初始化语法创建它:

select Envelope<_>( Id = event.Id, StreamId = streamId, ... )

为什么将select移动到Seq.map工作
Seq.map调用不是查询表达式的一部分.它不会最终成为IQueryable的一部分,因此它最终不会被Entity Framework编译为SQL.相反,EF编译内部查询的内容,并在从SQL Server获取后返回结果序列.然后才将Seq.map应用于该序列.
Seq.map中的代码在CLR上执行,而不是编译为SQL,因此它可以调用它想要的任何东西,包括非默认构造函数.
这个“修复”虽然带来了成本:不仅仅是你需要的字段,整个Event实体都是从DB获取并实现的.如果此实体很重,则可能会对性能产生影响.

另外需要注意的事项
即使您通过将Envelope设置为具有默认构造函数的类型(如上所述)来解决问题,您仍然会遇到下一个问题:方法JsonConvert.DeserializeObject无法编译为SQL,因此Entity Framework会抱怨它,太.你应该这样做的方法是将所有字段提取到CLR端,然后应用你需要的任何非SQL可编译的转换.

转载注明原文:entity-framework – f#:LINQ to Entities中仅支持无参数构造函数和初始值设定项 - 代码日志