delphi – 如何在高DPI系统中获得真正的屏幕分辨率?

因此,Delphi程序不支持DPI.直到最近我需要在具有高DPI的计算机中使用真正的屏幕分辨率(Wrong resolution reported by Screen.Width when “Make it easier to read what’s on screen” is 150%)时,这并没有太多困扰我.一些建议是使应用程序高DPI感知(XML清单),但其他人警告我们这涉及很多工作!所以,懒惰(或缺乏时间),我想知道是否有一个技巧来计算真正的分辨率.

我想到的一个非常脏的技巧是创建一个支持DPI的配套工具(微控制台应用程序).我所要做的就是调用这个工具并从中获得真正的分辨率.
相当斯巴达但它应该工作.无论如何,必须有一个更好的方法来做到这一点!

最佳答案
Win32_DesktopMonitor WMI类将产生信息.

例如,使用从此处获取的代码:Delphi7: Get attached monitor properties

{$APPTYPE CONSOLE}

uses
  SysUtils,
  ActiveX,
  ComObj,
  Variants;

function VarStrNull(VarStr: OleVariant): string;
// dummy function to handle null variants
begin
  Result := '';
  if not VarIsNull(VarStr) then
    Result := VarToStr(VarStr);
end;

procedure GetMonitorInfo;
var
  objWMIService: OleVariant;
  colItems: OleVariant;
  colItem: OleVariant;
  oEnum: IEnumvariant;
  iValue: LongWord;

  function GetWMIObject(const objectName: String): IDispatch;
  var
    chEaten: Integer;
    BindCtx: IBindCtx;
    Moniker: IMoniker;
  begin
    OleCheck(CreateBindCtx(0, BindCtx));
    OleCheck(MkParseDisplayName(BindCtx, StringToOleStr(objectName), chEaten,
      Moniker));
    OleCheck(Moniker.BindToObject(BindCtx, nil, IDispatch, Result));
  end;

begin
  objWMIService := GetWMIObject('winmgmts:\\localhost\root\CIMV2');
  colItems := objWMIService.ExecQuery
    ('SELECT * FROM Win32_DesktopMonitor', 'WQL', 0);
  oEnum := IUnknown(colItems._NewEnum) as IEnumvariant;
  while oEnum.Next(1, colItem, iValue) = 0 do
  begin
    Writeln('Caption      ' + VarStrNull(colItem.Caption));
    Writeln('Device ID    ' + VarStrNull(colItem.DeviceID));
    Writeln('Width        ' + VarStrNull(colItem.ScreenWidth));
    Writeln('Height       ' + VarStrNull(colItem.ScreenHeight));
    Writeln;
  end;
end;

begin
  try
    CoInitialize(nil);
    try
      GetMonitorInfo;
      Readln;
    finally
      CoUninitialize;
    end;
  except
    on E: Exception do
    begin
      Writeln(E.Classname, ': ', E.Message);
      Readln;
    end;
  end;
end.

如果由于任何原因WMI不可用,那么您需要一个单独的DPI识别过程来完成工作.这还需要一些IPC.

另一个问题是最新版本的Windows改变了这些WMI类的行为.您可能需要使用不同的WMI查询.见:https://social.msdn.microsoft.com/Forums/windowsdesktop/en-US/138d387c-b222-4c9f-b3bb-c69ee890491c/problem-with-win32desktopmonitor-in-windows-8-platform?forum=windowsgeneraldevelopmentissues

转载注明原文:delphi – 如何在高DPI系统中获得真正的屏幕分辨率? - 代码日志